project(
  'graphics-test',
  'cpp',
  version: '0.1.0',
  default_options: ['cpp_std=c++20', 'warning_level=everything', 'buildtype=debugoptimized'],
)

cpp = meson.get_compiler('cpp')

common_cpp_args = [
  '-Wno-c++20-compat',
  '-Wno-c++20-extensions',
  '-Wno-c++98-compat',
  '-Wno-c++98-compat-pedantic',
  '-Wno-disabled-macro-expansion',
  '-Wno-missing-prototypes',
  '-Wno-padded',
  '-Wno-pre-c++20-compat-pedantic',
  '-Wno-switch-default',
  '-Wno-unsafe-buffer-usage',
  '-Wunused-function',
  '-fvisibility=hidden',
]

add_project_arguments(cpp.get_supported_arguments(common_cpp_args), language: 'cpp')

source_file_names = [
  'src/main.cpp',
]

sources = []

foreach file : source_file_names
  sources += files(file)
endforeach

deps = [
  dependency('fmt', include_type: 'system'),
  dependency('glfw3', include_type: 'system'),
  dependency('glm', include_type: 'system'),
  dependency('vulkan', include_type: 'system'),
]

executable(
  'graphics-test',
  sources,
  include_directories: include_directories('include', is_system: true),
  dependencies: deps,
)